# Model Reference · Flux

Model Reference

## Basic Layers

These core layers form the foundation of almost all neural networks.

`Flux.Chain` — Type.

    Chain(layers...)

Chain multiple layers / functions together, so that they are called in sequence on a given input.

    m = Chain(x -> x^2, x -> x+1)
    m(5) == 26

    m = Chain(Dense(10, 5), Dense(5, 2))
    x = rand(10)
    m(x) == m[2](m[1](x))

`Chain` also supports indexing and slicing, e.g. `m[2]` or `m[1:end-1]`. `m[1:3](x)` will calculate the output of the first three layers.

source
`Flux.Dense` — Type.

    Dense(in::Integer, out::Integer, σ = identity)

Creates a traditional `Dense` layer with parameters `W` and `b`.

    y = σ.(W * x .+ b)

The input `x` must be a vector of length `in`, or a batch of vectors represented as an `in × N` matrix. The out `y` will be a vector or batch of length `out`.

    julia> d = Dense(5, 2)
    Dense(5, 2)

    julia> d(rand(5))
    Tracked 2-element Array{Float64,1}:
      0.00257447
      -0.00449443

source

## Convolution and Pooling Layers

These layers are used to build convolutional neural networks (CNNs).

`Flux.Conv` — Type.

    Conv(size, in=>out)
    Conv(size, in=>out, relu)

Standard convolutional layer. `size` should be a tuple like `(2, 2)`. `in` and `out` specify the number of input and output channels respectively.

Example: Applying Conv layer to a 1-channel input using a 2x2 window size, giving us a 16-channel output. Output is activated with ReLU.

    size = (2,2)
    in = 1
    out = 16
    Conv((2, 2), 1=>16, relu)

Data should be stored in WHCN order (width, height, # channels, # batches). In other words, a 100×100 RGB image would be a `100×100×3×1` array, and a batch of 50 would be a `100×100×3×50` array.

Takes the keyword arguments `pad`, `stride` and `dilation`.

source
`Flux.MaxPool` — Type.

    MaxPool(k)

Max pooling layer. `k` stands for the size of the window for each dimension of the input.

Takes the keyword arguments `pad` and `stride`.

source
`Flux.MeanPool` — Type.

    MeanPool(k)

Mean pooling layer. `k` stands for the size of the window for each dimension of the input.

Takes the keyword arguments `pad` and `stride`.

source
`Flux.DepthwiseConv` — Type.

    DepthwiseConv(size, in=>out)
    DepthwiseConv(size, in=>out, relu)

Depthwise convolutional layer. `size` should be a tuple like `(2, 2)`. `in` and `out` specify the number of input and output channels respectively. Note that `out` must be an integer multiple of `in`.

Data should be stored in WHCN order. In other words, a 100×100 RGB image would be a `100×100×3` array, and a batch of 50 would be a `100×100×3×50` array.

Takes the keyword arguments `pad`, `stride` and `dilation`.

source
`Flux.ConvTranspose` — Type.

    ConvTranspose(size, in=>out)
    ConvTranspose(size, in=>out, relu)

Standard convolutional transpose layer. `size` should be a tuple like `(2, 2)`. `in` and `out` specify the number of input and output channels respectively.

Data should be stored in WHCN order. In other words, a 100×100 RGB image would be a `100×100×3` array, and a batch of 50 would be a `100×100×3×50` array.

Takes the keyword arguments `pad`, `stride` and `dilation`.

source
`Flux.CrossCor` — Type.

    CrossCor(size, in=>out)
    CrossCor(size, in=>out, relu)

Standard cross convolutional layer. `size` should be a tuple like `(2, 2)`. `in` and `out` specify the number of input and output channels respectively.

Example: Applying CrossCor layer to a 1-channel input using a 2x2 window size, giving us a 16-channel output. Output is activated with ReLU.

    size = (2,2)
    in = 1
    out = 16
    CrossCor((2, 2), 1=>16, relu)

Data should be stored in WHCN order (width, height, # channels, # batches). In other words, a 100×100 RGB image would be a `100×100×3×1` array, and a batch of 50 would be a `100×100×3×50` array.

Takes the keyword arguments `pad`, `stride` and `dilation`.

source

## Recurrent Layers

Much like the core layers above, but can be used to process sequence data (as well as other kinds of structured data).

`Flux.RNN` — Function.

    RNN(in::Integer, out::Integer, σ = tanh)

The most basic recurrent layer; essentially acts as a `Dense` layer, but with the output fed back into the input each time step.

source
`Flux.LSTM` — Function.

    LSTM(in::Integer, out::Integer)

Long Short Term Memory recurrent layer. Behaves like an RNN but generally exhibits a longer memory span over sequences.

See this article for a good overview of the internals.

source
`Flux.GRU` — Function.

    GRU(in::Integer, out::Integer)

Gated Recurrent Unit layer. Behaves like an RNN but generally exhibits a longer memory span over sequences.

See this article for a good overview of the internals.

source
`Flux.Recur` — Type.

    Recur(cell)

`Recur` takes a recurrent cell and makes it stateful, managing the hidden state in the background. `cell` should be a model of the form:

    h, y = cell(h, x...)

For example, here's a recurrent network that keeps a running total of its inputs.

    accum(h, x) = (h+x, x)
    rnn = Flux.Recur(accum, 0)
    rnn(2) # 2
    rnn(3) # 3
    rnn.state # 5
    rnn.(1:10) # apply to a sequence
    rnn.state # 60

source

## Other General Purpose Layers

These are marginally more obscure than the Basic Layers. But in contrast to the layers described in the other sections are not readily grouped around a particular purpose (e.g. CNNs or RNNs).

`Flux.Maxout` — Type.

    Maxout(over)

`Maxout` is a neural network layer, which has a number of internal layers, which all have the same input, and the maxout returns the elementwise maximium of the internal layers' outputs.

Maxout over linear dense layers satisfies the univeral approximation theorem.

Reference: Ian J. Goodfellow, David Warde-Farley, Mehdi Mirza, Aaron Courville, and Yoshua Bengio.

1. Maxout networks.

In Proceedings of the 30th International Conference on International Conference on Machine Learning - Volume 28 (ICML'13), Sanjoy Dasgupta and David McAllester (Eds.), Vol. 28. JMLR.org III-1319-III-1327. https://arxiv.org/pdf/1302.4389.pdf

source
`Flux.SkipConnection` — Type.

    SkipConnection(layers, connection)

Creates a Skip Connection, of a layer or `Chain` of consecutive layers plus a shortcut connection. The connection function will combine the result of the layers with the original input, to give the final output.

The simplest 'ResNet'-type connection is just `SkipConnection(layer, +)`, and requires the output of the layers to be the same shape as the input. Here is a more complicated example:

    m = Conv((3,3), 4=>7, pad=(1,1))
    x = ones(5,5,4,10);
    size(m(x)) == (5, 5, 7, 10)

    sm = SkipConnection(m, (mx, x) -> cat(mx, x, dims=3))
    size(sm(x)) == (5, 5, 11, 10)

source

## Activation Functions

Non-linearities that go between layers of your model. Most of these functions are defined in NNlib but are available by default in Flux.

Note that, unless otherwise stated, activation functions operate on scalars. To apply them to an array you can call `σ.(xs)`, `relu.(xs)` and so on.

`NNlib.σ` — Function.

    σ(x) = 1 / (1 + exp(-x))

Classic sigmoid activation function.

`NNlib.relu` — Function.

    relu(x) = max(0, x)

Rectified Linear Unit activation function.

`NNlib.leakyrelu` — Function.

    leakyrelu(x) = max(0.01x, x)

Leaky Rectified Linear Unit activation function. You can also specify the coefficient explicitly, e.g. `leakyrelu(x, 0.01)`.

`NNlib.elu` — Function.

    elu(x, α = 1) =
      x > 0 ? x : α * (exp(x) - 1)

Exponential Linear Unit activation function. See Fast and Accurate Deep Network Learning by Exponential Linear Units. You can also specify the coefficient explicitly, e.g. `elu(x, 1)`.

`NNlib.swish` — Function.

    swish(x) = x * σ(x)

Self-gated activation function. See Swish: a Self-Gated Activation Function.

## Normalisation & Regularisation

These layers don't affect the structure of the network but may improve training times or reduce overfitting.

`Flux.BatchNorm` — Type.

    BatchNorm(channels::Integer, σ = identity;
              initβ = zeros, initγ = ones,
              ϵ = 1e-8, momentum = .1)

Batch Normalization layer. The `channels` input should be the size of the channel dimension in your data (see below).

Given an array with `N` dimensions, call the `N-1`th the channel dimension. (For a batch of feature vectors this is just the data dimension, for `WHCN` images it's the usual channel dimension.)

`BatchNorm` computes the mean and variance for each each `W×H×1×N` slice and shifts them to have a new mean and variance (corresponding to the learnable, per-channel `bias` and `scale` parameters).

See Batch Normalization: Accelerating Deep Network Training by Reducing Internal Covariate Shift.

Example:

    m = Chain(
      Dense(28^2, 64),
      BatchNorm(64, relu),
      Dense(64, 10),
      BatchNorm(10),
      softmax)

source
`Flux.Dropout` — Type.

    Dropout(p, dims = :)

A Dropout layer. For each input, either sets that input to `0` (with probability `p`) or scales it by `1/(1-p)`. The `dims` argument is to specified the unbroadcasted dimensions, i.e. `dims=1` does dropout along columns and `dims=2` along rows. This is used as a regularisation, i.e. it reduces overfitting during training. see also `dropout`.

source
`Flux.AlphaDropout` — Type.

    AlphaDropout(p)

A dropout layer. It is used in Self-Normalizing Neural Networks. (https://papers.nips.cc/paper/6698-self-normalizing-neural-networks.pdf) The AlphaDropout layer ensures that mean and variance of activations remains the same as before.

source
`Flux.LayerNorm` — Type.

    LayerNorm(h::Integer)

A normalisation layer designed to be used with recurrent hidden states of size `h`. Normalises the mean/stddev of each input before applying a per-neuron gain/bias.

source
`Flux.GroupNorm` — Type.

Group Normalization. This layer can outperform Batch-Normalization and Instance-Normalization.

    GroupNorm(chs::Integer, G::Integer, λ = identity;
              initβ = (i) -> zeros(Float32, i), initγ = (i) -> ones(Float32, i),
              ϵ = 1f-5, momentum = 0.1f0)

$chs$ is the number of channels, the channel dimension of your input. For an array of N dimensions, the (N-1)th index is the channel dimension.

$G$ is the number of groups along which the statistics would be computed. The number of channels must be an integer multiple of the number of groups.

Example:

    m = Chain(Conv((3,3), 1=>32, leakyrelu;pad = 1),
              GroupNorm(32,16)) # 32 channels, 16 groups (G = 16), thus 2 channels per group used

Link : https://arxiv.org/pdf/1803.08494.pdf

source