# Optimisers · Flux

# Optimisers

Consider a simple linear regression. We create some dummy data, calculate a loss, and backpropagate to calculate gradients for the parameters `W` and `b`.

    using Flux

    W = rand(2, 5)
    b = rand(2)

    predict(x) = (W * x) .+ b
    loss(x, y) = sum((predict(x) .- y).^2)

    x, y = rand(5), rand(2) # Dummy data
    l = loss(x, y) # ~ 3

    θ = Params([W, b])
    grads = gradient(() -> loss(x, y), θ)

We want to update each parameter, using the gradient, in order to improve (reduce) the loss. Here's one way to do that:

    using Flux.Optimise: update!

    η = 0.1 # Learning Rate
    for p in (W, b)
      update!(p, -η * grads[p])
    end

Running this will alter the parameters `W` and `b` and our loss should go down. Flux provides a more general way to do optimiser updates like this.

    opt = Descent(0.1) # Gradient descent with learning rate 0.1

    for p in (W, b)
      update!(opt, p, grads[p])
    end

An optimiser `update!` accepts a parameter and a gradient, and updates the parameter according to the chosen rule. We can also pass `opt` to our training loop, which will update all parameters of the model in a loop. However, we can now easily replace `Descent` with a more advanced optimiser such as `ADAM`.

## Optimiser Reference

All optimisers return an object that, when passed to `train!`, will update the parameters passed to it.

`Flux.Optimise.update!` — Function

    update!(x, x̄)

Update the array `x` according to `x .-= x̄`.

source

    update!(opt, p, g)
    update!(opt, ps::Params, gs)

Perform an update step of the parameters `ps` (or the single parameter `p`) according to optimizer `opt` and the gradients `gs` (the gradient `g`).

As a result, the parameters are mutated and the optimizer's internal state may change.

source
`Flux.Optimise.Descent` — Type

    Descent(η = 0.1)

Classic gradient descent optimiser with learning rate `η`. For each parameter `p` and its gradient `δp`, this runs `p -= η*δp`

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.

Examples

    opt = Descent()

    opt = Descent(0.3)

    ps = params(model)

    gs = gradient(ps) do
        loss(x, y)
    end

    Flux.Optimise.update!(opt, ps, gs)

source
`Flux.Optimise.Momentum` — Type

    Momentum(η = 0.01, ρ = 0.9)

Gradient descent optimizer with learning rate `η` and momentum `ρ`.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Momentum (`ρ`): Controls the acceleration of gradient descent in the prominent direction, in effect dampening oscillations.

Examples

    opt = Momentum()

    opt = Momentum(0.01, 0.99)

source
`Flux.Optimise.Nesterov` — Type

    Nesterov(η = 0.001, ρ = 0.9)

Gradient descent optimizer with learning rate `η` and Nesterov momentum `ρ`.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Nesterov momentum (`ρ`): Controls the acceleration of gradient descent in the prominent direction, in effect dampening oscillations.

Examples

    opt = Nesterov()

    opt = Nesterov(0.003, 0.95)

source
`Flux.Optimise.RMSProp` — Type

    RMSProp(η = 0.001, ρ = 0.9)

Optimizer using the RMSProp algorithm. Often a good choice for recurrent networks. Parameters other than learning rate generally don't need tuning.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Momentum (`ρ`): Controls the acceleration of gradient descent in the prominent direction, in effect dampening oscillations.

Examples

    opt = RMSProp()

    opt = RMSProp(0.002, 0.95)

source
`Flux.Optimise.ADAM` — Type

    ADAM(η = 0.001, β::Tuple = (0.9, 0.999))

ADAM optimiser.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Decay of momentums (`β::Tuple`): Exponential decay for the first (β1) and the second (β2) momentum estimate.

Examples

    opt = ADAM()

    opt = ADAM(0.001, (0.9, 0.8))

source
`Flux.Optimise.RADAM` — Type

    RADAM(η = 0.001, β::Tuple = (0.9, 0.999))

Rectified ADAM optimizer.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Decay of momentums (`β::Tuple`): Exponential decay for the first (β1) and the second (β2) momentum estimate.

Examples

    opt = RADAM()

    opt = RADAM(0.001, (0.9, 0.8))

source
`Flux.Optimise.AdaMax` — Type

    AdaMax(η = 0.001, β::Tuple = (0.9, 0.999))

AdaMax is a variant of ADAM based on the ∞-norm.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Decay of momentums (`β::Tuple`): Exponential decay for the first (β1) and the second (β2) momentum estimate.

Examples

    opt = AdaMax()

    opt = AdaMax(0.001, (0.9, 0.995))

source
`Flux.Optimise.ADAGrad` — Type

    ADAGrad(η = 0.1)

ADAGrad optimizer. It has parameter specific learning rates based on how frequently it is updated. Parameters don't need tuning.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.

Examples

    opt = ADAGrad()

    opt = ADAGrad(0.001)

source
`Flux.Optimise.ADADelta` — Type

    ADADelta(ρ = 0.9)

ADADelta is a version of ADAGrad adapting its learning rate based on a window of past gradient updates. Parameters don't need tuning.

Parameters

- Rho (`ρ`): Factor by which the gradient is decayed at each time step.

Examples

    opt = ADADelta()

    opt = ADADelta(0.89)

source
`Flux.Optimise.AMSGrad` — Type

    AMSGrad(η = 0.001, β::Tuple = (0.9, 0.999))

The AMSGrad version of the ADAM optimiser. Parameters don't need tuning.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Decay of momentums (`β::Tuple`): Exponential decay for the first (β1) and the second (β2) momentum estimate.

Examples

    opt = AMSGrad()

    opt = AMSGrad(0.001, (0.89, 0.995))

source
`Flux.Optimise.NADAM` — Type

    NADAM(η = 0.001, β::Tuple = (0.9, 0.999))

NADAM is a Nesterov variant of ADAM. Parameters don't need tuning.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Decay of momentums (`β::Tuple`): Exponential decay for the first (β1) and the second (β2) momentum estimate.

Examples

    opt = NADAM()

    opt = NADAM(0.002, (0.89, 0.995))

source
`Flux.Optimise.ADAMW` — Function

    ADAMW(η = 0.001, β::Tuple = (0.9, 0.999), decay = 0)

ADAMW is a variant of ADAM fixing (as in repairing) its weight decay regularization.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- Decay of momentums (`β::Tuple`): Exponential decay for the first (β1) and the second (β2) momentum estimate.
- `decay`: Decay applied to weights during optimisation.

Examples

    opt = ADAMW()

    opt = ADAMW(0.001, (0.89, 0.995), 0.1)

source

## Optimiser Interface

Flux's optimisers are built around a `struct` that holds all the optimiser parameters along with a definition of how to apply the update rule associated with it. We do this via the `apply!` function which takes the optimiser as the first argument followed by the parameter and its corresponding gradient.

In this manner Flux also allows one to create custom optimisers to be used seamlessly. Let's work this with a simple example.

    mutable struct Momentum
      eta
      rho
      velocity
    end

    Momentum(eta::Real, rho::Real) = Momentum(eta, rho, IdDict())

The `Momentum` type will act as our optimiser in this case. Notice that we have added all the parameters as fields, along with the velocity which we will use as our state dictionary. Each parameter in our models will get an entry in there. We can now define the rule applied when this optimiser is invoked.

    function Flux.Optimise.apply!(o::Momentum, x, Δ)
      η, ρ = o.eta, o.rho
      v = get!(o.velocity, x, zero(x))::typeof(x)
      @. v = ρ * v - η * Δ
      @. Δ = -v
    end

This is the basic definition of a Momentum update rule given by:

\[v = ρ * v - η * Δ w = w - v\]

The `apply!` defines the update rules for an optimiser `opt`, given the parameters and gradients. It returns the updated gradients. Here, every parameter `x` is retrieved from the running state `v` and subsequently updates the state of the optimiser.

Flux internally calls on this function via the `update!` function. It shares the API with `apply!` but ensures that multiple parameters are handled gracefully.

## Composing Optimisers

Flux defines a special kind of optimiser simply called `Optimiser` which takes in arbitrary optimisers as input. Its behaviour is similar to the usual optimisers, but differs in that it acts by calling the optimisers listed in it sequentially. Each optimiser produces a modified gradient that will be fed into the next, and the resultant update will be applied to the parameter as usual. A classic use case is where adding decays is desirable. Flux defines some basic decays including `ExpDecay`, `InvDecay` etc.

    opt = Optimiser(ExpDecay(0.001, 0.1, 1000, 1e-4), Descent())

Here we apply exponential decay to the `Descent` optimiser. The defaults of `ExpDecay` say that its learning rate will be decayed every 1000 steps. It is then applied like any optimiser.

    w = randn(10, 10)
    w1 = randn(10,10)
    ps = Params([w, w1])

    loss(x) = Flux.mse(w * x, w1 * x)

    loss(rand(10)) # around 9

    for t = 1:10^5
      θ = Params([w, w1])
      θ̄ = gradient(() -> loss(rand(10)), θ)
      Flux.Optimise.update!(opt, θ, θ̄)
    end

    loss(rand(10)) # around 0.9

In this manner it is possible to compose optimisers for some added flexibility.

## Decays

Similar to optimisers, Flux also defines some simple decays that can be used in conjunction with other optimisers, or standalone.

`Flux.Optimise.ExpDecay` — Type

    ExpDecay(η = 0.001, decay = 0.1, decay_step = 1000, clip = 1e-4)

Discount the learning rate `η` by the factor `decay` every `decay_step` steps till a minimum of `clip`.

Parameters

- Learning rate (`η`): Amount by which gradients are discounted before updating the weights.
- `decay`: Factor by which the learning rate is discounted.
- `decay_step`: Schedule decay operations by setting the number of steps between two decay operations.
- `clip`: Minimum value of learning rate.

Examples

To apply exponential decay to an optimiser:

    Optimiser(ExpDecay(..), Opt(..))

    opt = Optimiser(ExpDecay(), ADAM())

source
`Flux.Optimise.InvDecay` — Type

    InvDecay(γ = 0.001)

Apply inverse time decay to an optimiser, so that the effective step size at iteration `n` is `eta / (1 + γ * n)` where `eta` is the initial step size. The wrapped optimiser's step size is not modified.

Examples

    Optimiser(InvDecay(..), Opt(..))

source
`Flux.Optimise.WeightDecay` — Type

    WeightDecay(wd = 0)

Decay weights by `wd`.

Parameters

- Weight decay (`wd`)

source

Theme

This document was generated with Documenter.jl on Monday 4 May 2020. Using Julia version 1.3.1.